/*
 * SPDX-FileCopyrightText: 2013, microG Project Team
 * SPDX-License-Identifier: Apache-2.0
 */

buildscript {
    ext.applicationNamespace = "com.google.android.gms"
    ext.basePackageName = "com.mgoogle"

    ext.safeParcelVersion = '1.7.1'

    ext.kotlinVersion = '1.7.21'
    ext.coroutineVersion = '1.6.4'

    ext.annotationVersion = '1.5.0'
    ext.appcompatVersion = '1.6.1'
    ext.coreVersion = '1.9.0'
    ext.collectionVersion = '1.3.0-dev01'
    ext.fragmentVersion = '1.5.5'
    ext.lifecycleVersion = '2.5.1'
    ext.materialVersion = '1.7.0'
    ext.navigationVersion = '2.5.3'
    ext.preferenceVersion = '1.2.0'
    ext.webkitVersion = '1.5.0'

    ext.circleimageviewVersion = '3.1.0'
    ext.volleyVersion = '1.2.1'
    ext.wireVersion = '4.8.0'


    ext.androidBuildGradleVersion = '8.0.2'
    ext.androidBuildVersionTools = '33.0.2'

    ext.androidMinSdk = 23
    ext.androidTargetSdk = 30
    ext.androidCompileSdk = 33

    repositories {
        mavenCentral()
        google()
    }

    dependencies {
        classpath "com.android.tools.build:gradle:$androidBuildGradleVersion"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "com.squareup.wire:wire-gradle-plugin:$wireVersion"
    }
}


def gmsVersion = "25.09.34"
def gmsVersionCode = Integer.parseInt(gmsVersion.replaceAll('\\.', ''))

def ourVersionBase = "0.3.0"

def ourVersionCode = gmsVersionCode * 1000
def ourVersionName = "$ourVersionBase.$gmsVersionCode"

allprojects {
    apply plugin: 'idea'

    group = 'org.microg.gms'
    version = ourVersionName
    ext.appVersionCode = ourVersionCode
    ext.isReleaseVersion = false
}

subprojects {
    repositories {
        mavenCentral()
        google()
    }
    afterEvaluate {
        // Temporary hack for Android Studio
        if (project.plugins.hasPlugin('com.android.base')) {
            dependencies {
                compileOnly "org.microg:safe-parcel:$safeParcelVersion"
                testCompileOnly "org.microg:safe-parcel:$safeParcelVersion"
            }
        }
    }
}